part number	NF, dB @ 1.5 GHz	Gp, dB @ 1.5 GHz	package	outline	data sheet	FAX
INA-03100	2.5 typ	26.0 typ	chip		pdf
INA-03170	2.5 typ 3.0 max	28.0 typ 24.5 min	70 mil ceramic		pdf
INA-03184	2.6 typ	25.0 typ 23.0 min	85 mil plastic trim lead		pdf	55498

packages: 00, 70, 84
 

SPICE model

* INA-03 DIE MODEL
* Combine with package model to complete

* DIE MODEL
XNA03 DIEOUT  DIEIN   DIEGND  INA03
.ENDS
* chip model
.SUBCKT INA03   DIEOUT  DIEIN   DIEGND

RBIAS1   Q2E     14     330        (TC1=-0.8E-3)
RBIAS2   Q3E     14     520          (TC1=-0.8E-3)
RE2      Q3E      DIEGND  50    (TC1=-0.8E-3)
RF1      DIEIN   14    750         (TC1=-0.8E-3)
RF2      Q1C      DIEOUT  700  (TC1=-0.8E-3)
LP1      11          DIEGND   0.20NH

LP2      15          DIEGND   0.20NH
CP1      11          DIEGND   0.35PF
CP2      15          DIEGND   0.50PF
C3     DIEOUT  DIEGND   0.25PF
C4       Q1C       DIEGND    0.036PF
C5     DIEIN      DIEGND    0.086PF
C13    Q2E        DIEGND    0.023PF
C14      14          DIEGND   0.036PF
CCOMP     Q3E       20       1.25PF
RES       20       DIEGND    25
XNA03Q1  Q1C       DIEIN   Q1E   DIEGND    a03Q1
XNA03Q2  DIEOUT  Q1C    Q2E   DIEGND    a03Q2
XNA03Q3  DIEOUT  Q2E    Q3E   DIEGND    a03Q3

.ENDS
* Q1 distributed base model
.SUBCKT a03Q1   Q1C     Q1B     Q1E    Q1S
RC1      6      5    6.5       (TC1=0.6E-3)
RC2      5      Q1C    22.5       (TC1=0.6E-3)
RB1     Q1B     7     2.4     (TC1=0.8E-3)
RB2     7      8     7.5    (TC1=1.2E-3)
RB3     8      B1     6.3     (TC1=1.8E-3)
RE      E1      Q1E    0.55    (TC1=0.6E-3)
Q1      C1      B1     E1      QINA    180
DCD1    Q1B     C1     DMOD    292
DCD2    7      C1     DMOD    292
DCD3    8      C1     DMOD    146

DCS    5      Q1S     DMOD    1419
.ENDS
* Q2 distributed base model
.SUBCKT a03Q2   Q2C     Q2B     Q2E    Q2S
RC1      6      5    5.5       (TC1=0.6E-3)
RC2      5      Q2C    80       (TC1=0.6E-3)
RB1     Q2B     7     8.4     (TC1=0.8E-3)
RB2     7      8     28    (TC1=1.2E-3)
RB3     8      B1     23.5     (TC1=1.8E-3)
RE      E1      Q2E    2.1    (TC1=0.6E-3)
Q1      C1      B1     E1      QINA    48
DCD1    Q2B     C1     DMOD    123
DCD2    7      C1     DMOD    79

DCD3    8      C1     DMOD    40
DCS    5      Q2S     DMOD    756
.ENDS
* Q3 distributed base model
.SUBCKT a03Q3   Q3C     Q3B     Q3E    Q3S
RC1      6      5    7       (TC1=0.6E-3)
RC2      5      Q3C    27       (TC1=0.6E-3)
RB1     Q3B     7     3.6     (TC1=0.8E-3)
RB2     7      8     11.2    (TC1=1.2E-3)
RB3     8      B1     9.4     (TC1=1.8E-3)
RE      E1      Q3E    0.83    (TC1=0.6E-3)
Q1      C1      B1     E1      QINA    120
DCD1    Q3B     C1     DMOD    209

DCD2    7      C1     DMOD    198
DCD3    8      C1     DMOD    99
DCS    5      Q3S     DMOD2    1092
.ENDS

.MODEL  DMOD    D(IS=1E-25, CJO=2.4E-16, VJ=.76,
+               M=.53, BV=45)
.MODEL  DMOD2   D(IS=1E-25, CJO=1.2E-16, VJ=.80,
+               M=.50, BV=45, RS=1.0E+06)
.MODEL  QINA    NPN (BF=100, BR=2.5, IS=1.7E-18,
+               VA=20, TF=12PS, CJE=2.4E-15, VJE=1.01,
+               MJE=0.6, PTF=25, XTB=1.818, VTF=6,
+               ITF=3E-4, IKF=1.3E-4, XTF=4, NF=1.03,
+               ISE=5E-15, NE=2.5)

To complete the IC model, the above die model must be combined
with one of the following package models.

INA-03100		package 00 model
INA-03170		package 70 model
INA-03184		package 84 model

file name	description
a03100IB.s2p	INA-03100 s parameters at 12 mA	view
a03170IB.s2p	INA-03170 s and noise parameters at 12 mA	view
a03184ia.s2p	INA-03184 s parameters at 10 mA	view

General Information about Amplifier ICs
Information about INA Series IC Amplifiers
Assembly Information