part number	NF, dB @ 1 GHz	Gp, dB @ 1 GHz	package	outline	data sheet
MSA-2011	4.3 typ	16.2 typ 15.0 min	SOT-143		pdf
MSA-2035	3.7 typ	17.3 typ @ 1 GHz 17.8 min 19.8 max @ 0.1 GHz	micro-x		pdf
MSA-2085	3.7 typ	16.6 typ 15.0 min	85 mil plastic		pdf
MSA-2086	3.7 typ	16.6 typ 15.0 min	SMT 85 mil plastic		pdf

packages: 11 35 85 86

* MSA-20 MODEL
* Combine with package model to complete

* DIE MODEL
XA20 DIEOUT  DIEIN   DIEGND  MSA20
.ENDS

* chip model
.SUBCKT MSA20   DIEOUT  DIEIN   DIEGND
RF      DIEIN   DIEOUT  670     (TC1=-0.8E-3)
RE      Q2E     DIEGND  2.9     (TC1=-0.8E-3)
RB      DIEIN   DIEGND  350     (TC1=-0.8E-3)
RBIAS   Q1E     DIEGND  75      (TC1=-0.8E-3)
CF      DIEIN   DIEOUT  0.04PF
CP1     Q1E     DIEOUT  0.05PF
CP2     Q2E     DIEOUT  0.15PF
CP3     DIEGND  DIEOUT  0.25PF
XA20Q1  DIEOUT  DIEIN   Q1E     A20Q1
XA20Q2  DIEOUT  Q1E     Q2E     A20Q2
.ENDS

* Q1 distributed base model
.SUBCKT A20Q1   Q1C     Q1B     Q1E
RB1     Q1B     11     2.42    (TC1=0.8E-3)
RB2     11      12     7.45    (TC1=1.2E-3)
RB3     12      B1     6.25    (TC1=1.8E-3)
RE      E1      Q1E    0.55    (TC1=0.6E-3)
RC      C1      Q1C    5       (TC1=0.6E-3)
Q1      C1      B1     E1      QMSA    180
DCD1    Q1B     C1     DMOD    292
DCD2    11      C1     DMOD    292
DCD3    12      C1     DMOD    146
.ENDS

* Q2 distributed base model
.SUBCKT A20Q2   Q2C     Q2B     Q2E
RB1     Q2B     21     1.48    (TC1=0.8E-3)
RB2     21      22     4.47    (TC1=1.2E-3)
RB3     22      B2     3.75    (TC1=1.8E-3)
RE      E2      Q2E    0.33    (TC1=0.6E-3)
RC      C2      Q2C    5       (TC1=0.6E-3)
Q1      C2      B2     E2      QMSA    300
DCD1    Q2B     C2     DMOD    432
DCD2    21      C2     DMOD    486
DCD3    22      C2     DMOD    243
.ENDS


.MODEL  DMOD    D(IS=1E-25, CJO=2.45E-16, VJ=.76,
+               M=.53, BV=45, IBV=1E-9)
.MODEL  QMSA    NPN (BF=90, BR=5, IS=1.65E-18, VA=20,
+               TF=12PS, CJE=1.8E-15, VJE=1.01, MJE=0.6,
+               PTF=25, XTB=1.818, VTF=6, ITF=3E-4,
+               IKF=1.333E-4, XTF=4, NF=1.03, ISE=5E-15,
+               NE=2.5)

MSA-2011		package 11 model
MSA-2035		package 35 model
MSA-2085		package 85 model
MSA-2086		package 86 model

file name	description
a2011i32.s2p	MSA-2011 s parameters at 32 mA	view
a2035i32.s2p	MSA-2035 s parameters at 32 mA	view
a2085i32.s2p	MSA-2085 s parameters at 32 mA	view
a2086i32.s2p	MSA-2086 s parameters at 32 mA	view

General Information about Amplifier ICs
Information about MSA Series IC Amplifiers
Assembly Information